Expression: CommaExpression
An expression is a sequence of operators and operands that specifies an evaluation. The syntax, order of evaluation, and semantics of expressions are as follows.
Expressions are used to compute values with a resulting type. These values can then be assigned, tested, or ignored. Expressions can also have side effects.
For any expression expr, the full expression of expr is defined as follows. If expr parses as a subexpression of another expression expr1, then the full expression of expr is the full expression of expr1. Otherwise, expr is its own full expression.
Each expression has a unique full expression. Example:
return f() + g() * 2;
The full expression of g() * 2 above is f() + g() * 2, but not the full expression of f() + g() because the latter is not parsed as a subexpression.
Note: Although the definition is straightforward, a few subtleties exist related to function literals:
return (() => x + f())() * g();
The full expression of f() above is x + f(), not the expression passed to return. This is because the parent of x + f() has function literal type, not expression type.
The following expressions, and no others, are called lvalue expressions or lvalues:
Expressions that are not lvalues are rvalues. Rvalues include all literals, special value keywords such as __FILE__ and __LINE__, enum values, and the result of expressions not defined as lvalues above.
The built-in address-of operator (unary &) may only be applied to lvalues.
Given an expression expr that is a subexpression of a full expression fullexpr, the smallest short-circuit expression, if any, is the shortest subexpression scexpr of fullexpr that is an AndAndExpression (&&) or an OrOrExpression (||), such that expr is a subexpression of scexpr. Example:
((f() * 2 && g()) + 1) || h()The smallest short-circuit expression of the subexpression f() * 2 above is f() * 2 && g(). Example:
(f() && g()) + h()The subexpression h() above has no smallest short-circuit expression.
Built-in prefix unary expressions ++ and -- are evaluated as if lowered (rewritten) to assignments as follows:
| Expression | Equivalent |
|---|---|
| ++expr | ((expr) += 1) |
| --expr | ((expr) -= 1) |
Therefore, the result of prefix ++ and -- is the lvalue after the side effect has been effected.
Built-in postfix unary expressions ++ and -- are evaluated as if lowered (rewritten) to lambda invocations as follows:
| Expression | Equivalent |
|---|---|
| expr++ | (ref x){auto t = x; ++x; return t;}(expr) |
| expr-- | (ref x){auto t = x; --x; return t;}(expr) |
Therefore, the result of postfix ++ and -- is an rvalue just before the side effect has been effected.
Binary expressions except for AssignExpression, OrOrExpression, and AndAndExpression are evaluated in lexical order (left-to-right). Example:
int i = 2; i = ++i * i++ + i; assert(i == 3 * 3 + 4);
OrOrExpression and AndAndExpression evaluate their left-hand side argument first. Then, OrOrExpression evaluates its right-hand side if and only if its left-hand side does not evaluate to nonzero. AndAndExpression evaluates its right-hand side if and only if its left-hand side evaluates to nonzero.
ConditionalExpression evaluates its left-hand side argument first. Then, if the result is nonzero, the second operand is evaluated. Otherwise, the third operand is evaluated.
Calls to functions with extern(D) linkage (which is the default linkage) are evaluated in the following order: first, if necessary, the address of the function to call is evaluated (e.g. in the case of a computed function pointer or delegate). Then, arguments are evaluated left to right. Finally, transfer is passed to the function. Example:
import std.stdio; void function(int a, int b, int c) fun() { writeln("fun() called"); static void r(int a, int b, int c) { writeln("callee called"); } return &r; } int f1() { writeln("f1() called"); return 1; } int f2() { writeln("f2() called"); return 2; } int f3(int x) { writeln("f3() called"); return x + 3; } int f4() { writeln("f4() called"); return 4; } // evaluates fun() then f1() then f2() then f3() then f4() // after which control is transferred to the callee fun()(f1(), f3(f2()), f4());
Expressions and statements may create and/or consume rvalues. Such values are called temporaries and do not have a name or a visible scope. Their lifetime is managed automatically as defined in this section.
For each evaluation that yields a temporary value, the lifetime of that temporary begins at the evaluation point, similarly to creation of a usual named value initialized with an expression.
Termination of lifetime of temporaries does not obey the customary scoping rules and is defined as follows:
If a subexpression of an expression throws an exception, all temporaries created up to the evaluation of that subexpression will be destroyed per the rules above. No destructor calls will be issued for temporaries not yet constructed.
Note: An intuition behind these rules is that destructors of temporaries are deferred to the end of full expression and in reverse order of construction, with the exception that the right-hand side of && and || are considered their own full expressions even when part of larger expressions.
Note: The ConditionalExpression e1 ? e2 : e3 is not a special case although it evaluates expressions conditionally: e1 and one of e2 and e3 may create temporaries. Their destructors are inserted to the end of the full expression in the reverse order of creation.
Example:
import std.stdio; struct S { int x; this(int n) { x = n; writefln("S(%s)", x); } ~this() { writefln("~S(%s)", x); } } bool b = (S(1) == S(2) || S(3) != S(4)) && S(5) == S(6);
S(1) S(2) S(3) S(4) ~S(4) ~S(3) S(5) S(6) ~S(6) ~S(5) ~S(2) ~S(1)First, S(1) and S(2) are evaluated in lexical order. Per the rules, they will be destroyed at the end of the full expression and in reverse order. The comparison S(1) == S(2) yields false, so the right-hand side of the || is evaluated causing S(3) and S(4) to be evaluated, also in lexical order. However, their destruction is not deferred to the end of the full expression. Instead, S(4) and then S(3) are destroyed at the end of the || expression. Following their destruction, S(5) and S(6) are constructed in lexical order. Again they are not destroyed at the end of the full expression, but right at the end of the && expression. Consequently, the destruction of S(6) and S(5) is carried before that of S(2) and S(1).
CommaExpression: AssignExpression CommaExpression , AssignExpression
The left operand of the , is evaluated, then the right operand is evaluated. The type of the expression is the type of the right operand, and the result is the result of the right operand. Using the result of comma expressions isn't allowed.
AssignExpression: ConditionalExpression ConditionalExpression = AssignExpression ConditionalExpression += AssignExpression ConditionalExpression -= AssignExpression ConditionalExpression *= AssignExpression ConditionalExpression /= AssignExpression ConditionalExpression %= AssignExpression ConditionalExpression &= AssignExpression ConditionalExpression |= AssignExpression ConditionalExpression ^= AssignExpression ConditionalExpression ~= AssignExpression ConditionalExpression <<= AssignExpression ConditionalExpression >>= AssignExpression ConditionalExpression >>>= AssignExpression ConditionalExpression ^^= AssignExpression
For all assign expressions, the left operand must be a modifiable lvalue. The type of the assign expression is the type of the left operand, and the result is the value of the left operand after assignment occurs. The resulting expression is a modifiable lvalue.
If the operator is = then it is simple assignment.
Otherwise, the right operand is implicitly converted to the type of the left operand, and assigned to it.
For arguments of built-in types, assignment operator expressions such as
a op= bare semantically equivalent to:
a = cast(typeof(a))(a op b)except that:
For user-defined types, assignment operator expressions are overloaded separately from the binary operators. Still the left operand must be an lvalue.
ConditionalExpression: OrOrExpression OrOrExpression ? Expression : ConditionalExpression
The first expression is converted to bool, and is evaluated.
If it is true, then the second expression is evaluated, and its result is the result of the conditional expression.
If it is false, then the third expression is evaluated, and its result is the result of the conditional expression.
If either the second or third expressions are of type void, then the resulting type is void. Otherwise, the second and third expressions are implicitly converted to a common type which becomes the result type of the conditional expression.
Note: When a conditional expression is the left operand of an assign expression, parentheses are required for disambiguation:
bool test; int a, b, c; ... test ? a = b : c = 2; // Deprecated (test ? a = b : c) = 2; // Equivalent
This makes the intent clearer, because the first statement can easily be misread as the following code:
test ? a = b : (c = 2);
OrOrExpression: AndAndExpression OrOrExpression || AndAndExpression
The result type of an OrOrExpression is bool, unless the right operand has type void, when the result is type void.
The OrOrExpression evaluates its left operand.
If the left operand, converted to type bool, evaluates to true, then the right operand is not evaluated. If the result type of the OrOrExpression is bool then the result of the expression is true.
If the left operand is false, then the right operand is evaluated. If the result type of the OrOrExpression is bool then the result of the expression is the right operand converted to type bool.
AndAndExpression: OrExpression AndAndExpression && OrExpression
The result type of an AndAndExpression is bool, unless the right operand has type void, when the result is type void.
The AndAndExpression evaluates its left operand.
If the left operand, converted to type bool, evaluates to false, then the right operand is not evaluated. If the result type of the AndAndExpression is bool then the result of the expression is false.
If the left operand is true, then the right operand is evaluated. If the result type of the AndAndExpression is bool then the result of the expression is the right operand converted to type bool.
Bit wise expressions perform a bitwise operation on their operands. Their operands must be integral types. First, the Usual Arithmetic Conversions are done. Then, the bitwise operation is done.
OrExpression: XorExpression OrExpression | XorExpression
The operands are OR'd together.
XorExpression: AndExpression XorExpression ^ AndExpression
The operands are XOR'd together.
AndExpression: CmpExpression AndExpression & CmpExpression
The operands are AND'd together.
CmpExpression: EqualExpression IdentityExpression RelExpression InExpression ShiftExpression
EqualExpression: ShiftExpression == ShiftExpression ShiftExpression != ShiftExpression
Equality expressions compare the two operands for equality (==) or inequality (!=). The type of the result is bool.
Inequality is defined as the logical negation of equality.
If the operands are integral values, the Usual Arithmetic Conversions are applied to bring them to a common type before comparison. Equality is defined as the bit patterns of the common type match exactly.
If the operands are pointers, equality is defined as the bit patterns of the operands match exactly.
For float, double, and real values, the Usual Arithmetic Conversions are applied to bring them to a common type before comparison. The values -0 and +0 are considered equal. If either or both operands are NaN, then == returns false and != returns true. Otherwise, the bit patterns of the common type are compared for equality.
For static and dynamic arrays, equality is defined as the lengths of the arrays matching, and all the elements are equal.
x.re == y.re && x.im == y.im
For struct objects, equality means the result of the opEquals() member function. If an opEquals() is not provided, equality is defined as the logical product of all equality results of the corresponding object fields.
For class and struct objects, the expression (a == b) is rewritten as a.opEquals(b), and (a != b) is rewritten as !a.opEquals(b).
For class objects, the == and != operators are intended to compare the contents of the objects, however an appropriate opEquals override must be defined for this to work. The default opEquals provided by the root Object class is equivalent to the is operator (see below). Comparing against null is invalid, as null has no contents. Use the is and !is operators instead.
class C; C c; if (c == null) // error ... if (c is null) // ok ...
IdentityExpression: ShiftExpression is ShiftExpression ShiftExpression ! is ShiftExpression
The is operator compares for identity. To compare for nonidentity, use e1 !is e2. The type of the result is bool. The operands undergo the Usual Arithmetic Conversions to bring them to a common type before comparison.
For class objects, identity is defined as the object references are for the same object. Null class objects can be compared with is.
For struct objects and floating point values, identity is defined as the bits in the operands being identical.
For static and dynamic arrays, identity of two arrays is given when both arrays refer to the same memory location and contain the same number of elements.
Object o; assert(o is null); auto a = [1, 2]; assert(a is a[0..$]); assert(a !is a[0..1]); auto b = [1, 2]; assert(a !is b);
For other operand types, identity is defined as being the same as equality.
The identity operator is cannot be overloaded.
RelExpression: ShiftExpression < ShiftExpression ShiftExpression <= ShiftExpression ShiftExpression > ShiftExpression ShiftExpression >= ShiftExpression
First, the Usual Arithmetic Conversions are done on the operands. The result type of a relational expression is bool.
For static and dynamic arrays, the result of a CmpExpression is the result of the operator applied to the first non-equal element of the array. If two arrays compare equal, but are of different lengths, the shorter array compares as "less" than the longer array.
Integer comparisons happen when both operands are integral types.
| Operator | Relation |
|---|---|
| < | less |
| > | greater |
| <= | less or equal |
| >= | greater or equal |
| == | equal |
| != | not equal |
It is an error to have one operand be signed and the other unsigned for a <, <=, > or >= expression. Use casts to make both operands signed or both operands unsigned.
If one or both operands are floating point, then a floating point comparison is performed.
A CmpExpression can have NaN operands. If either or both operands is NaN, the floating point comparison operation returns as follows:
| Operator | Relation | Returns |
|---|---|---|
| < | less | false |
| > | greater | false |
| <= | less or equal | false |
| >= | greater or equal | false |
| == | equal | false |
| != | unordered, less, or greater | true |
For class objects, EqualExpression and RelExpression compare the contents of the objects. Therefore, comparing against a null class reference is invalid, as null has no contents.
class C {} C c; //if (c < null) {} // compile-time error assert(c is null); if (c > new C) {} // runtime error
For class objects, the result of Object.opCmp() forms the left operand, and 0 forms the right operand. The result of an EqualExpression or RelExpression (o1 op o2) is:
(o1.opCmp(o2) op 0)
InExpression: ShiftExpression in ShiftExpression ShiftExpression ! in ShiftExpression
A container such as an associative array can be tested to see if it contains a certain key:
int foo[string]; ... if ("hello" in foo) { // the string was found }
The result of an InExpression is a pointer for associative arrays. The pointer is null if the container has no matching key. If there is a match, the pointer points to a value associated with the key.
The !in expression is the logical negation of the in operation.
The in expression has the same precedence as the relational expressions <, <=, etc.
ShiftExpression: AddExpression ShiftExpression << AddExpression ShiftExpression >> AddExpression ShiftExpression >>> AddExpression
The operands must be integral types, and undergo the Integer Promotions. The result type is the type of the left operand after the promotions. The result value is the result of shifting the bits by the right operand's value.
int c; int s = -3; auto y = c << s; // implementation defined value auto x = c << 33; // error, max shift count allowed is 31
AddExpression: MulExpression AddExpression + MulExpression AddExpression - MulExpression CatExpression
If the operands are of integral types, they undergo the Usual Arithmetic Conversions, and then are brought to a common type using the Usual Arithmetic Conversions.
If both operands are of integral types and an overflow or underflow occurs in the computation, wrapping will happen. For example:
If either operand is a floating point type, the other is implicitly converted to floating point and they are brought to a common type via the Usual Arithmetic Conversions.
Add expressions for floating point operands are not associative.
If the operator is + or -, and the first operand is a pointer, and the second is an integral type, the resulting type is the type of the first operand, and the resulting value is the pointer plus (or minus) the second operand multiplied by the size of the type pointed to by the first operand.
int[] a = [1,2,3]; int* p = a.ptr; assert(*p == 1); *(p + 2) = 4; // same as `p[2] = 4` assert(a[2] == 4);
IndexExpression can also be used with a pointer and has the same behaviour as adding an integer, then dereferencing the result.
If the second operand is a pointer, and the first is an integral type, and the operator is +, the operands are reversed and the pointer arithmetic just described is applied.
Producing a pointer through pointer arithmetic is not allowed in @safe code.
If both operands are pointers, and the operator is +, then it is illegal.
If both operands are pointers, and the operator is -, the pointers are subtracted and the result is divided by the size of the type pointed to by the operands. In this calculation the assumed size of void is one byte. It is an error if the pointers point to different types. The type of the result is ptrdiff_t.
int[] a = [1,2,3]; ptrdiff_t d = &a[2] - a.ptr; assert(d == 2);
CatExpression: AddExpression ~ MulExpression
A CatExpression concatenates a container's data with other data, producing a new container.
For a dynamic array, the other operand must either be another array or a single value that implicitly converts to the element type of the array. See Array Concatenation.
MulExpression: UnaryExpression MulExpression * UnaryExpression MulExpression / UnaryExpression MulExpression % UnaryExpression
The operands must be arithmetic types. They undergo the Usual Arithmetic Conversions.
For integral operands, the *, /, and % correspond to multiply, divide, and modulus operations. For multiply, overflows are ignored and simply chopped to fit into the integral type.
For integral operands of the / and % operators, the quotient rounds towards zero and the remainder has the same sign as the dividend.
The following divide or modulus integral operands:
are illegal if encountered during Compile Time Execution.
For floating point operands, the * and / operations correspond to the IEEE 754 floating point equivalents. % is not the same as the IEEE 754 remainder. For example, 15.0 % 10.0 == 5.0, whereas for IEEE 754, remainder(15.0,10.0) == -5.0.
Mul expressions for floating point operands are not associative.
UnaryExpression: & UnaryExpression ++ UnaryExpression -- UnaryExpression * UnaryExpression - UnaryExpression + UnaryExpression ! UnaryExpression ComplementExpression DeleteExpression CastExpression ThrowExpression PowExpression
| Operator | Description |
|---|---|
| & | Take memory address of an lvalue - see pointers |
| ++ | Increment before use - see order of evaluation |
| -- | Decrement before use |
| * | Dereference/indirection - typically for pointers |
| - | Negative |
| + | Positive |
| ! | Logical NOT |
The usual Integer Promotions are performed prior to unary - and + operations.
ComplementExpression: ~ UnaryExpression
ComplementExpressions work on integral types (except bool). All the bits in the value are complemented. The usual Integer Promotions are performed prior to the complement operation.
DeleteExpression: delete UnaryExpression
If the UnaryExpression is a class object reference, and there is a destructor for that class, the destructor is called for that object instance.
Next, if the UnaryExpression is a class object reference, or a pointer to a struct instance, and the class or struct has overloaded operator delete, then that operator delete is called for that class object instance or struct instance.
Otherwise, the garbage collector is called to immediately free the memory allocated for the class instance or struct instance.
If the UnaryExpression is a pointer or a dynamic array, the garbage collector is called to immediately release the memory.
The pointer, dynamic array, or reference is set to null after the delete is performed. Any attempt to reference the data after the deletion via another reference to it will result in undefined behavior.
If UnaryExpression is a variable allocated on the stack, the class destructor (if any) is called for that instance. The garbage collector is not called.
CastExpression: cast ( Type ) UnaryExpression CastQual
A CastExpression converts the UnaryExpression to Type.
cast(foo) -p; // cast (-p) to type foo (foo) - p; // subtract p from foo
Any casting of a class reference to a derived class reference is done with a runtime check to make sure it really is a downcast. null is the result if it isn't.
class A {} class B : A {} void main() { A a = new A; //B b = a; // error, need cast B b = cast(B) a; // b is null if a is not a B assert(b is null); a = b; // no cast needed a = cast(A) b; // no runtime check needed for upcast assert(a is b); }
In order to determine if an object o is an instance of a class B use a cast:
if (cast(B) o) { // o is an instance of B } else { // o is not an instance of B }
Casting a pointer type to and from a class type is done as a type paint (i.e. a reinterpret cast).
Casting a dynamic array to another dynamic array is done only if the array lengths multiplied by the element sizes match. The cast is done as a type paint, with the array length adjusted to match any change in element size. If there's not a match, a runtime error is generated.
byte[] a = [1,2,3]; //auto b = cast(int[])a; // runtime error: array cast misalignment int[] c = [1, 2, 3]; auto d = cast(byte[])c; // ok // prints: // [1, 0, 0, 0, 2, 0, 0, 0, 3, 0, 0, 0] writeln(d);
Casting a static array to another static array is done only if the array lengths multiplied by the element sizes match; a mismatch is illegal. The cast is done as a type paint (aka a reinterpret cast). The contents of the array are not changed.
byte[16] b = 3; // set each element to 3 assert(b[0] == 0x03); int[4] ia = cast(int[4]) b; // print elements as hex foreach (i; ia) writefln("%x", i); /* prints: 3030303 3030303 3030303 3030303 */
Casting an integer to a smaller integral will truncate the value towards the least significant bits. If the target type is signed and the most significant bit is set after truncation, that bit will be lost from the value and the sign bit will be set.
uint a = 260; auto b = cast(ubyte) a; assert(b == 4); // truncated like 260 & 0xff int c = 128; assert(cast(byte)c == -128); // reinterpreted
Converting between signed and unsigned types will reinterpret the value if the destination type cannot represent the source value.
short c = -1; ushort d = c; assert(d == ushort.max); assert(uint(c) == uint.max); ubyte e = 255; byte f = e; assert(f == -1); // reinterpreted assert(short(e) == 255); // no change
Casting a floating point literal from one type to another changes its type, but internally it is retained at full precision for the purposes of constant folding.
void test() { real a = 3.40483L; real b; b = 3.40483; // literal is not truncated to double precision assert(a == b); assert(a == 3.40483); assert(a == 3.40483L); assert(a == 3.40483F); double d = 3.40483; // truncate literal when assigned to variable assert(d != a); // so it is no longer the same const double x = 3.40483; // assignment to const is not assert(x == a); // truncated if the initializer is visible }
Casting a floating point value to an integral type is the equivalent of converting to an integer using truncation. If the floating point value is outside the range of the integral type, the cast will produce an invalid result (this is also the case in C, C++).
void main() { int a = cast(int) 0.8f; assert(a == 0); long b = cast(long) 1.5; assert(b == 1L); long c = cast(long) -1.5; assert(c == -1); // if the float overflows, the cast returns the integer value of // 80000000_00000000H (64-bit operand) or 80000000H (32-bit operand) long d = cast(long) float.max; assert(d == long.min); int e = cast(int) (1234.5 + int.max); assert(e == int.min); // for types represented on 16 or 8 bits, the result is the same as // 32-bit types, but the most significant bits are ignored short f = cast(short) float.max; assert(f == 0); }
Casting a value v to a struct S, when value is not a struct of the same type, is equivalent to:
S(v)
CastQual: cast ( TypeCtorsopt ) UnaryExpression
A CastQual replaces the qualifiers in the type of the UnaryExpression:
shared int x; static assert(is(typeof(cast(const)x) == const int));
Casting with no type or qualifiers removes any top level const, immutable, shared or inout type modifiers from the type of the UnaryExpression.
shared int x; static assert(is(typeof(cast()x) == int));
Casting an expression to void type is allowed to mark that the result is unused. On ExpressionStatement, it could be used properly to avoid a "has no effect" error.
void foo(lazy void exp) {} void main() { foo(10); // NG - expression '10' has no effect foo(cast(void)10); // OK }
ThrowExpression: throw AssignExpression
AssignExpression is evaluated and must yield a reference to a Throwable or a class derived from Throwable. The reference is thrown as an exception, interrupting the current control flow to continue at a suitable catch clause of a try-statement. This process will execute any applicable scope (exit) / scope (failure) passed since entering the corresponding try block.
throw new Exception("message");
A ThrowExpression may be nested in another expression:
void foo(int function() f) {} void main() { foo(() => throw new Exception()); }
The type of a ThrowExpression is noreturn.
PowExpression: PostfixExpression PostfixExpression ^^ UnaryExpression
PowExpression raises its left operand to the power of its right operand.
PostfixExpression: PrimaryExpression PostfixExpression . Identifier PostfixExpression . TemplateInstance PostfixExpression . NewExpression PostfixExpression ++ PostfixExpression -- PostfixExpression ( ArgumentListopt ) TypeCtorsopt BasicType ( ArgumentListopt ) IndexExpression SliceExpression
| Operator | Description |
|---|---|
| . | Either: |
| ++ | Increment after use - see order of evaluation |
| -- | Decrement after use |
| IndexExpression | Select a single element |
| SliceExpression | Select a series of elements |
IndexExpression: PostfixExpression [ ArgumentList ]
PostfixExpression is evaluated. If PostfixExpression is an expression of static or dynamic array type, the result of the indexing is an lvalue of the ith element in the array, where i is an integer evaluated from ArgumentList. If PostfixExpression is a pointer p, the result is *(p + i) (see Pointer Arithmetic).
If PostfixExpression is a ValueSeq then the ArgumentList must consist of only one argument, and that must be statically evaluatable to an integral constant. That integral constant n then selects the nth expression in the ValueSeq, which is the result of the IndexExpression. It is an error if n is out of bounds of the ValueSeq.
The special variable $ is declared and set to be the number of elements in the PostfixExpression (when available). A new declaration scope is created for the evaluation of the ArgumentList and $ appears in that scope only.
The index operator can be overloaded. Using multiple indices in ArgumentList is only supported for operator overloading.
SliceExpression: PostfixExpression [ ] PostfixExpression [ Slice ,opt ] Slice: AssignExpression AssignExpression , Slice AssignExpression .. AssignExpression AssignExpression .. AssignExpression , Slice
PostfixExpression is evaluated. If PostfixExpression is a static or dynamic array a, the result of the slice is a dynamic array referencing elements a[i] to a[j-1] inclusive, where i and j are integers evaluated from the first and second AssignExpression respectively.
If PostfixExpression is a pointer p, the result will be a dynamic array referencing elements from p[i] to p[j-1] inclusive, where i and j are integers evaluated from the first and second AssignExpression respectively.
If PostfixExpression is a ValueSeq, then the result of the slice is a new ValueSeq formed from the upper and lower bounds, which must statically evaluate to integral constants. It is an error if those bounds are out of range.
The first AssignExpression is taken to be the inclusive lower bound of the slice, and the second AssignExpression is the exclusive upper bound. The result of the expression is a slice of the elements in PostfixExpression.
The special variable $ is declared and set to be the number of elements in the PostfixExpression (when available). A new declaration scope is created for the evaluation of the AssignExpression..AssignExpression and $ appears in that scope only.
If the [ ] form is used, the slice is of all the elements in PostfixExpression. The expression cannot be a pointer.
The slice operator can be overloaded. Using more than one Slice is only supported for operator overloading.
A SliceExpression is not a modifiable lvalue.
If the slice bounds can be known at compile time, the slice expression may be implicitly convertible to a static array lvalue. For example:
arr[a .. b] // typed T[]
If both a and b are integers (which may be constant-folded), the slice expression can be converted to a static array of type T[b - a].
void f(int[2] sa); int[] arr = [1, 2, 3]; //f(arr); // error, can't convert f(arr[1 .. 3]); // OK //f(arr[0 .. 3]); // error int[2] g() { return arr[0 .. 2]; }
void bar(ref int[2] a) { assert(a == [2, 3]); a = [4, 5]; } void main() { int[] arr = [1, 2, 3]; // slicing an lvalue gives an lvalue bar(arr[1 .. 3]); assert(arr == [1, 4, 5]); }
PrimaryExpression: Identifier . Identifier TemplateInstance . TemplateInstance this super null true false $ IntegerLiteral FloatLiteral CharacterLiteral StringLiteral ArrayLiteral AssocArrayLiteral FunctionLiteral AssertExpression MixinExpression ImportExpression NewExpression FundamentalType . Identifier ( Type ) . Identifier ( Type ) . TemplateInstance FundamentalType ( ArgumentListopt ) TypeCtor ( Type ) . Identifier TypeCtor ( Type ) ( ArgumentListopt ) Typeof TypeidExpression IsExpression ( Expression ) SpecialKeyword TraitsExpression
Within a non-static member function, this resolves to a reference to the object for which the function was called.
typeof(this) is valid anywhere inside an aggregate type definition. If a class member function is called with an explicit reference to typeof(this), a non-virtual call is made:
class A { char get() { return 'A'; } char foo() { return typeof(this).get(); } char bar() { return this.get(); } } class B : A { override char get() { return 'B'; } } void main() { B b = new B(); assert(b.foo() == 'A'); assert(b.bar() == 'B'); }
Assignment to this is not allowed for classes.
super is identical to this, except that it is cast to this's base class. It is an error if there is no base class. It is an error to use the super reference outside a non-static class member function. (Only class Object has no base class.) If a member function is called with an explicit reference to super, a non-virtual call is made.
Assignment to super is not allowed.
null represents the null value for pointers, pointers to functions, delegates, dynamic arrays, associative arrays, and class objects. If it has not already been cast to a type, it is given the singular type typeof(null) and it is an exact conversion to convert it to the null value for pointers, pointers to functions, delegates, etc. After it is cast to a type, such conversions are implicit, but no longer exact.
StringLiteral: WysiwygString AlternateWysiwygString DoubleQuotedString DelimitedString TokenString
String literals can implicitly convert to any of the following types, they have equal weight:
| immutable(char)* |
| immutable(wchar)* |
| immutable(dchar)* |
| immutable(char)[] |
| immutable(wchar)[] |
| immutable(dchar)[] |
By default, a string literal is typed as a dynamic array, but the element count is known at compile time. So all string literals can be implicitly converted to static array types.
void foo(char[2] a) { assert(a == "bc"); } void bar(ref const char[2] a) { assert(a == "bc"); } void baz(const char[3] a) {} void main() { string str = "abc"; foo(str[1 .. 3]); bar(str[1 .. 3]); //baz(str[1 .. 3]); // cannot match length }
String literals have a 0 appended to them, which makes them easy to pass to C or C++ functions expecting a const char* string. The 0 is not included in the .length property of the string literal.
Concatenation of string literals requires the use of the ~ operator, and is resolved at compile time. C style implicit concatenation without an intervening operator is error prone and not supported in D.
ArrayLiteral: [ ArrayMemberInitializationsopt ] ArrayMemberInitializations: ArrayMemberInitialization ArrayMemberInitialization , ArrayMemberInitialization , ArrayMemberInitializations ArrayMemberInitialization: NonVoidInitializer AssignExpression : NonVoidInitializer
An array literal is a comma-separated list of expressions between square brackets [ and ]. The expressions form the elements of a dynamic array. The length of the array is the number of elements. The common type of all the elements is taken to be the array element type, and each expression is implicitly converted to that type.
auto a1 = [1,2,3]; // type is int[], with elements 1, 2 and 3 auto a2 = [1u,2,3]; // type is uint[], with elements 1u, 2u, and 3u
By default, an array literal is typed as a dynamic array, but the element count is known at compile time. Therefore, an array literal can be implicitly converted to a static array of the same length.
int[2] sa = [1, 2];
If any ArrayMemberInitialization is a ValueSeq, then the elements of the ValueSeq are inserted as expressions in place of the sequence.
Escaping array literals are allocated on the memory managed heap. Thus, they can be returned safely from functions:
int[] foo() { return [1, 2, 3]; }
To initialize an element at a particular index, use the AssignExpression : NonVoidInitializer syntax. The AssignExpression must be known at compile-time. Any missing elements will be initialized to the default value of the element type. Note that if the array type is not specified, the literal will be parsed as an associative array.
int n = 4; auto aa = [0:1, 3:n]; // associative array `int[int]` int[] a = [1, 3:n, 5]; assert(a == [1, 0, 0, n, 5]); //int[] e = [n:2]; // error, n not known at compile-time
When array literals are cast to another array type, each element of the array is cast to the new element type. When arrays that are not literals are cast, the array is reinterpreted as the new type, and the length is recomputed:
import std.stdio; void main() { // cast array literal const short[] ct = cast(short[]) [cast(byte)1, 1]; // this is equivalent with: // const short[] ct = [cast(short)1, cast(short)1]; writeln(ct); // writes [1, 1] // cast other array expression // --> normal behavior of CastExpression byte[] arr = [cast(byte)1, cast(byte)1]; short[] rt = cast(short[]) arr; writeln(rt); // writes [257] }
AssocArrayLiteral: [ KeyValuePairs ] KeyValuePairs: KeyValuePair KeyValuePair , KeyValuePairs KeyValuePair: KeyExpression : ValueExpression KeyExpression: AssignExpression ValueExpression: AssignExpression
Associative array literals are a comma-separated list of key:value pairs between square brackets [ and ]. The list cannot be empty. The common type of the all keys is taken to be the key type of the associative array, and all keys are implicitly converted to that type. The common type of the all values is taken to be the value type of the associative array, and all values are implicitly converted to that type. An AssocArrayLiteral cannot be used to statically initialize anything.
[21u: "he", 38: "ho", 2: "hi"]; // type is string[uint], // with keys 21u, 38u and 2u // and values "he", "ho", and "hi"
If any of the keys or values in the KeyValuePairs are a ValueSeq, then the elements of the ValueSeq are inserted as arguments in place of the sequence.
FunctionLiteral: function RefOrAutoRefopt Typeopt ParameterWithAttributesopt FunctionLiteralBody2 delegate RefOrAutoRefopt Typeopt ParameterWithMemberAttributesopt FunctionLiteralBody2 RefOrAutoRefopt ParameterWithMemberAttributes FunctionLiteralBody2 BlockStatement Identifier => AssignExpression ParameterWithAttributes: Parameters FunctionAttributesopt ParameterWithMemberAttributes: Parameters MemberFunctionAttributesopt FunctionLiteralBody2: => AssignExpression SpecifiedFunctionBody RefOrAutoRef: ref auto ref
FunctionLiterals (also known as Lambdas) enable embedding anonymous functions and anonymous delegates directly into expressions. Type is the return type of the function or delegate - if omitted it is inferred. ParameterWithAttributes or ParameterWithMemberAttributes can be used to specify the parameters for the function. If these are omitted, the function defaults to the empty parameter list ( ). The type of a function literal is a delegate or a pointer to function.
For example:
int function(char c) fp; // declare pointer to a function void test() { static int foo(char c) { return 6; } fp = &foo; }is exactly equivalent to:
int function(char c) fp; void test() { fp = function int(char c) { return 6; }; }
A delegate is necessary if the FunctionLiteralBody2 accesses any non-static local variables in enclosing functions.
int abc(int delegate(int i)); void test() { int b = 3; int foo(int c) { return 6 + b; } abc(&foo); }is exactly equivalent to:
int abc(int delegate(int i)); void test() { int b = 3; abc( delegate int(int c) { return 6 + b; } ); }
The use of ref declares that the return value is returned by reference:
void main() { int x; auto dg = delegate ref int() { return x; }; x = 3; assert(dg() == 3); }
If a literal omits function or delegate and there's no expected type from the context, then it is inferred to be a delegate if it accesses a variable in an enclosing function, otherwise it is a function pointer.
void test() { int b = 3; auto fp = (uint c) { return c * 2; }; // inferred as function pointer auto dg = (int c) { return 6 + b; }; // inferred as delegate static assert(!is(typeof(fp) == delegate)); static assert(is(typeof(dg) == delegate)); }
If a delegate is expected, the literal will be inferred as a delegate even if it accesses no variables from an enclosing function:
void abc(int delegate(int i)) {} void def(uint function(uint s)) {} void test() { int b = 3; abc( (int c) { return 6 + b; } ); // inferred as delegate abc( (int c) { return c * 2; } ); // inferred as delegate def( (uint c) { return c * 2; } ); // inferred as function //def( (uint c) { return c * b; } ); // error! // Because the FunctionLiteral accesses b, its type // is inferred as delegate. But def cannot accept a delegate argument. }
If the type of a function literal can be uniquely determined from its context, parameter type inference is possible.
void foo(int function(int) fp); void test() { int function(int) fp = (n) { return n * 2; }; // The type of parameter n is inferred as int. foo((n) { return n * 2; }); // The type of parameter n is inferred as int. }
auto fp = (i) { return 1; }; // error, cannot infer type of `i`
If a function literal is aliased, the inference of the parameter types is done when the types are needed, as the function literal becomes a template.
alias fpt = (i) { return i; }; // ok, infer type of `i` when used //auto fpt(T)(T i) { return i; } // equivalent auto v = fpt(4); // `i` is inferred as int auto d = fpt(10.3); // `i` is inferred as double alias fp = fpt!float; auto f = fp(0); // f is a float
The return type of the FunctionLiteral can be inferred from either the AssignExpression, or any ReturnStatements in the BlockStatement. If there is a different expected type from the context, and the initial inferred return type implicitly converts to the expected type, then the return type is inferred as the expected type.
auto fi = (int i) { return i; }; static assert(is(typeof(fi(5)) == int)); long function(int) fl = (int i) { return i; }; static assert(is(typeof(fl(5)) == long));
Anonymous delegates can behave like arbitrary statement literals. For example, here an arbitrary statement is executed by a loop:
void loop(int n, void delegate() statement) { foreach (_; 0 .. n) { statement(); } } void main() { int n = 0; loop(5, { n += 1; }); assert(n == 5); }
The syntax => AssignExpression is equivalent to { return AssignExpression; }.
void main() { auto i = 3; auto twice = function (int x) => x * 2; assert(twice(i) == 6); auto square = delegate () => i * i; assert(square() == 9); auto n = 5; auto mul_n = (int x) => x * n; assert(mul_n(i) == 15); }
The syntax Identifier => AssignExpression is equivalent to (Identifier) { return AssignExpression; }.
// the following two declarations are equivalent alias fp = i => 1; alias fp = (i) { return 1; };
int motor(alias fp)(int i) { return fp(i) + 1; } int engine() { return motor!(i => i * 2)(6); // returns 13 }
The implicit conversions of built-in scalar types can be explicitly represented by using function call syntax. For example:
auto a = short(1); // implicitly convert an integer literal '1' to short auto b = double(a); // implicitly convert a short variable 'a' to double auto c = byte(128); // error, 128 cannot be represented in a byte
If the argument is omitted, it means default construction of the scalar type:
auto a = ushort(); // same as: ushort.init auto b = wchar(); // same as: wchar.init
See also: Usual Arithmetic Conversions.
AssertExpression: assert ( AssertArguments ) AssertArguments: AssignExpression ,opt AssignExpression , AssignExpression ,opt
The first AssignExpression must evaluate to true. If it does not, an Assert Failure has occurred and the program enters an Invalid State.
If the first AssignExpression consists entirely of compile time constants, and evaluates to false, it is a special case; it signifies that it is unreachable code. Compile Time Function Execution (CTFE) is not attempted.
AssertExpression has different semantics if it is in a unittest or in contract.
The second AssignExpression, if present, must be implicitly convertible to type const(char)[].
If the first AssignExpression is a reference to a class instance for which a class Invariant exists, the class Invariant must hold.
If the first AssignExpression is a pointer to a struct instance for which a struct Invariant exists, the struct Invariant must hold.
The type of an AssertExpression is void.
void main() { assert(0, "an" ~ " error message"); }
When compiled and run, it will produce the message:
[email protected](3) an error message
The implementation may handle the case of the first AssignExpression evaluating at compile time to false differently in that in release mode it may simply generate a HLT instruction or equivalent.
MixinExpression: mixin ( ArgumentList )
Each AssignExpression in the ArgumentList is evaluated at compile time, and the result must be representable as a string. The resulting strings are concatenated to form a string. The text contents of the string must be compilable as a valid Expression, and is compiled as such.
int foo(int x) { return mixin("x +", 1) * 7; // same as ((x + 1) * 7) }
ImportExpression: import ( AssignExpression )
The AssignExpression must evaluate at compile time to a constant string. The text contents of the string are interpreted as a file name. The file is read, and the exact contents of the file become a string literal.
Implementations may restrict the file name in order to avoid directory traversal security vulnerabilities. A possible restriction might be to disallow any path components in the file name.
Note that by default an import expression will not compile unless one or more paths are passed via the -J switch. This tells the compiler where it should look for the files to import. This is a security feature.
void foo() { // Prints contents of file foo.txt writeln(import("foo.txt")); }
NewExpression: new Type new Type [ AssignExpression ] new Type ( ArgumentListopt ) NewAnonClassExpression ArgumentList: AssignExpression AssignExpression , AssignExpression , ArgumentList
NewExpressions are used to allocate memory on the garbage collected heap.
The Type form constructs an instance of a type and default-initializes it.
The Type(ArgumentList) form allows passing either a single initializer of the same type, or multiple arguments for more complex types. For class types, ArgumentList is passed to the class constructor. For a dynamic array, the argument sets the initial array length. For multidimensional dynamic arrays, each argument corresponds to an initial length.
int* i = new int; assert(*i == 0); i = new int(5); assert(*i == 5); Object o = new Object; Exception e = new Exception("info"); auto a = new int[](2); assert(a.length == 2); int[][] m = new int[][](10, 5); assert(m.length == 10); assert(m[0].length == 5);
The Type[AssignExpression] form allocates a dynamic array with length equal to AssignExpression. It is preferred to use the Type(ArgumentList) form when allocating dynamic arrays instead, as it is more general.
If a NewExpression is used with a class type as an initializer for a function local variable with scope storage class, then the instance is allocated on the stack.
new can also be used to allocate a nested class.
To allocate multidimensional arrays, the declaration reads in the same order as the prefix array declaration order.
char[][] foo; // dynamic array of strings ... foo = new char[][30]; // allocate array of 30 strings
The above allocation can also be written as:
foo = new char[][](30); // allocate array of 30 strings
To allocate the nested arrays, multiple arguments can be used:
int[][][] bar; ... bar = new int[][][](5, 20, 30);The code above is equivalent to:
bar = new int[][][5]; foreach (ref a; bar) { a = new int[][20]; foreach (ref b; a) { b = new int[30]; } }
TypeidExpression: typeid ( Type ) typeid ( Expression )
If Type, returns an instance of class TypeInfo corresponding to Type.
If Expression, returns an instance of class TypeInfo corresponding to the type of the Expression. If the type is a class, it returns the TypeInfo of the dynamic type (i.e. the most derived type). The Expression is always executed.
class A { } class B : A { } void main() { import std.stdio; writeln(typeid(int)); // int uint i; writeln(typeid(i++)); // uint writeln(i); // 1 A a = new B(); writeln(typeid(a)); // B writeln(typeid(typeof(a))); // A }
IsExpression: is ( Type ) is ( Type : TypeSpecialization ) is ( Type == TypeSpecialization ) is ( Type : TypeSpecialization , TemplateParameterList ) is ( Type == TypeSpecialization , TemplateParameterList ) is ( Type Identifier ) is ( Type Identifier : TypeSpecialization ) is ( Type Identifier == TypeSpecialization ) is ( Type Identifier : TypeSpecialization , TemplateParameterList ) is ( Type Identifier == TypeSpecialization , TemplateParameterList ) TypeSpecialization: Type struct union class interface enum __vector function delegate super const immutable inout shared return __parameters module package
IsExpressions are evaluated at compile time and are used for:
The result of an IsExpression is a boolean of value true if the condition is satisfied. If the condition is not satisfied, the result is a boolean of value false.
Type is the type being tested. It must be syntactically correct, but it need not be semantically correct. If it is not semantically correct, the condition is not satisfied.
TypeSpecialization is the type that Type is being pattern matched against.
IsExpressions may be used in conjunction with typeof to check whether an expression type checks correctly. For example, is(typeof(foo)) will return true if foo has a valid type.
The condition is satisfied if Type is semantically correct (it must be syntactically correct regardless).
alias int Func(int); // Func is a alias to a function type void foo() { if (is(Func[])) // not satisfied because arrays of // functions are not allowed writeln("satisfied"); else writeln("not satisfied"); if (is([][])) // error, [][] is not a syntactically valid type ... }
The condition is satisfied if Type is semantically correct and it is the same as or can be implicitly converted to TypeSpecialization. TypeSpecialization is only allowed to be a Type.
alias Bar = short; void foo() { if (is(Bar : int)) // satisfied because short can be // implicitly converted to int writeln("satisfied"); else writeln("not satisfied"); }
The condition is satisfied if Type is semantically correct and is the same type as TypeSpecialization.
alias Bar = short; void foo() { if (is(Bar == int)) // not satisfied because short is not // the same type as int writeln("satisfied"); else writeln("not satisfied"); }
If TypeSpecialization is one of
struct union class interface enum __vector function delegate const immutable inout shared module package then the condition is satisfied if Type is one of those.static assert(is(Object == class)); int i; static assert(!is(i == const));
Package modules are considered to be both packages and modules.
See also: Traits.
Identifier is declared to be an alias of the resulting type if the condition is satisfied. The Identifier forms can only be used if the IsExpression appears in a StaticIfCondition or StaticAssert.
The condition is satisfied if Type is semantically correct. If so, Identifier is declared to be an alias of Type.
alias Bar = short; void foo() { static if (is(Bar T)) alias S = T; else alias S = long; pragma(msg, S); // short // if T was defined, it remains in scope if (is(T)) pragma(msg, T); // short //if (is(Bar U)) {} // error, cannot declare U here }
The condition is satisfied if Type is semantically correct and it is the same as or can be implicitly converted to TypeSpecialization. TypeSpecialization is only allowed to be a Type. The Identifier is declared to be either an alias of the TypeSpecialization or, if TypeSpecialization is dependent on Identifier, the TypeSpecialization forms a pattern from which the type of Identifier is deduced.
alias Bar = int; static if (is(Bar T : int)) alias S = T; else alias S = long; static assert(is(S == int));
alias Abc = long*; static if (is(Abc U : U*)) // Abc is matched against the pattern U* { U u; } static assert(is(U == long));
The way the type of Identifier is determined is analogous to the way template parameter types are determined by TemplateTypeParameterSpecialization.
The condition is satisfied if Type is semantically correct and is the same as TypeSpecialization. The Identifier is declared to be either an alias of the TypeSpecialization or, if TypeSpecialization is dependent on Identifier, the TypeSpecialization forms a pattern from which the type of Identifier is deduced.
alias Bar = short; static if (is(Bar T == int)) // not satisfied, short is not int alias S = T; static assert(!is(T)); // T is not defined
If TypeSpecialization is one of struct union class interface enum __vector function delegate const immutable inout shared module package
then the condition is satisfied if Type is one of those. TypeSpecialization can also match the following keywords:| keyword | condition |
|---|---|
| super | true if Type is a class or interface |
| return | true is Type is a function, delegate or function pointer |
| __parameters | true is Type is a function, delegate or function pointer |
Furthermore, Identifier is set to be an alias of the type:
| keyword | alias type for Identifier |
|---|---|
| struct | Type |
| union | Type |
| class | Type |
| interface | Type |
| super | TypeSeq of base classes and interfaces |
| enum | the base type of the enum |
| __vector | the static array type of the vector |
| function | TypeSeq of the function parameter types. For C- and D-style variadic functions, only the non-variadic parameters are included. For typesafe variadic functions, the ... is ignored. |
| delegate | the function type of the delegate |
| return | the return type of the function, delegate, or function pointer |
| __parameters | the parameter sequence of a function, delegate, or function pointer. This includes the parameter types, names, and default values. |
| const | Type |
| immutable | Type |
| inout | Type |
| shared | Type |
| module | the module |
| package | the package |
enum E : byte { Emember } static if (is(E V == enum)) // satisfied, E is an enum V v; // v is declared to be a byte static assert(is(V == byte));
is ( Type : TypeSpecialization , TemplateParameterList ) is ( Type == TypeSpecialization , TemplateParameterList ) is ( Type Identifier : TypeSpecialization , TemplateParameterList ) is ( Type Identifier == TypeSpecialization , TemplateParameterList )
More complex types can be pattern matched; the TemplateParameterList declares symbols based on the parts of the pattern that are matched, analogously to the way implied template parameters are matched.
Example: Matching a Template Instantiation
struct Tuple(T...) { // ... } alias Tup2 = Tuple!(int, string); static if (is(Tup2 : Template!Args, alias Template, Args...)) { static assert(__traits(isSame, Template, Tuple)); static assert(is(Template!(int, string) == Tup2)); // same struct } static assert(is(Args[0] == int)); static assert(is(Args[1] == string));
Example: Matching an Associative Array
alias AA = long[string]; static if (is(AA T : T[U], U : string)) // T[U] is the pattern { pragma(msg, T); // long pragma(msg, U); // string } // no match, B is not an int static assert(!is(AA A : A[B], B : int));
Example: Matching a Static Array
static if (is(int[10] W : W[len], int len)) // W[len] is the pattern { static assert(len == 10); } static assert(is(W == int)); // no match, len should be 10 static assert(!is(int[10] X : X[len], int len : 5));
SpecialKeyword: __FILE__ __FILE_FULL_PATH__ __MODULE__ __LINE__ __FUNCTION__ __PRETTY_FUNCTION__
__FILE__ and __LINE__ expand to the source file name and line number at the point of instantiation. The path of the source file is left up to the compiler.
__FILE_FULL_PATH__ expands to the absolute source file name at the point of instantiation.
__MODULE__ expands to the module name at the point of instantiation.
__FUNCTION__ expands to the fully qualified name of the function at the point of instantiation.
__PRETTY_FUNCTION__ is similar to __FUNCTION__, but also expands the function return type, its parameter types, and its attributes.
Example:
module test; import std.stdio; void test(string file = __FILE__, size_t line = __LINE__, string mod = __MODULE__, string func = __FUNCTION__, string pretty = __PRETTY_FUNCTION__, string fileFullPath = __FILE_FULL_PATH__) { writefln("file: '%s', line: '%s', module: '%s',\nfunction: '%s', " ~ "pretty function: '%s',\nfile full path: '%s'", file, line, mod, func, pretty, fileFullPath); } int main(string[] args) { test(); return 0; }
Assuming the file was at /example/test.d, this will output:
file: 'test.d', line: '13', module: 'test', function: 'test.main', pretty function: 'int test.main(string[] args)', file full path: '/example/test.d'
An implementation may rearrange the evaluation of expressions according to arithmetic associativity and commutativity rules as long as, within that thread of execution, no observable difference is possible.
This rule precludes any associative or commutative reordering of floating point expressions.